cmake_minimum_required(VERSION 3.22.1)
project(sxw_android LANGUAGES C CXX)

# Reuse the exact runner from the framework source (tools/build_android.py
# passes every path explicitly).
get_filename_component(SXW_ROOT "${CMAKE_CURRENT_LIST_DIR}/../../../../.." ABSOLUTE)
get_filename_component(RECOMP_ROOT "${SXW_ROOT}/.." ABSOLUTE)
if(DEFINED SXW_FRAMEWORK_ROOT AND NOT "${SXW_FRAMEWORK_ROOT}" STREQUAL "")
    set(FRAMEWORK_ROOT "${SXW_FRAMEWORK_ROOT}")
elseif(DEFINED ENV{SXW_FRAMEWORK_ROOT} AND NOT "$ENV{SXW_FRAMEWORK_ROOT}" STREQUAL "")
    set(FRAMEWORK_ROOT "$ENV{SXW_FRAMEWORK_ROOT}")
else()
    set(FRAMEWORK_ROOT "${RECOMP_ROOT}/ndsrecomp")
endif()
set(RUNNER_ROOT "${FRAMEWORK_ROOT}/runner")
set(CMAKE_POSITION_INDEPENDENT_CODE ON)
set(NDS_SDL_BACKEND NONE CACHE STRING "" FORCE)
set(NDS_ENABLE_COMPUTE_RENDERER OFF CACHE BOOL "" FORCE)
# Windows and Unix title drivers generate in different directories. Explicit
# environment overrides take precedence and are useful for clean worktrees.
foreach(kind SYSTEM TITLE PROMOTION)
    set(override "SXW_${kind}_BANKS")
    if(DEFINED ${override} AND NOT "${${override}}" STREQUAL "")
        set(${kind}_BANKS "${${override}}")
    elseif(DEFINED ENV{${override}} AND NOT "$ENV{${override}}" STREQUAL "")
        set(${kind}_BANKS "$ENV{${override}}")
    elseif(kind STREQUAL "SYSTEM")
        if(EXISTS "${SXW_ROOT}/generated/windows/system/freebios_arm9.c")
            set(${kind}_BANKS "${SXW_ROOT}/generated/windows/system")
        else()
            set(${kind}_BANKS "${SXW_ROOT}/generated/system")
        endif()
    elseif(kind STREQUAL "TITLE")
        if(EXISTS "${SXW_ROOT}/generated/windows/recomp")
            set(${kind}_BANKS "${SXW_ROOT}/generated/windows/recomp")
        else()
            set(${kind}_BANKS "${SXW_ROOT}/generated/recomp")
        endif()
    else()
        if(EXISTS "${SXW_ROOT}/generated/promotion-windows/manifest.json")
            set(${kind}_BANKS "${SXW_ROOT}/generated/promotion-windows")
        else()
            set(${kind}_BANKS "${SXW_ROOT}/generated/promotion")
        endif()
    endif()
endforeach()
set(NDS_GENERATED_DIR "${SYSTEM_BANKS}" CACHE PATH "" FORCE)
set(NDS_TITLE_BANK_DIR "${TITLE_BANKS}" CACHE PATH "" FORCE)
set(NDS_TITLE_ROM_SHA1 "aee7dadd31becf0b33c5ac857a2c13978cb16bec" CACHE STRING "" FORCE)
if(EXISTS "${PROMOTION_BANKS}/manifest.json")
    set(NDS_TITLE_BANK_DIRS "${PROMOTION_BANKS}" CACHE STRING "" FORCE)
    set(NDS_TITLE_ROM_SHA1S "${NDS_TITLE_ROM_SHA1}" CACHE STRING "" FORCE)
else()
    # Clear stale Gradle/CMake cache entries if the optional promotion is absent.
    set(NDS_TITLE_BANK_DIRS "" CACHE STRING "" FORCE)
    set(NDS_TITLE_ROM_SHA1S "" CACHE STRING "" FORCE)
endif()
set(NDS_BOOTSTRAP_FIRMWARE ON CACHE BOOL "" FORCE)
if(DEFINED SXW_RECOMP_UI_ROOT AND NOT "${SXW_RECOMP_UI_ROOT}" STREQUAL "")
    set(UI_ROOT "${SXW_RECOMP_UI_ROOT}")
elseif(EXISTS "${FRAMEWORK_ROOT}/../recomp-ui/src")
    set(UI_ROOT "${FRAMEWORK_ROOT}/../recomp-ui")   # release kit layout: kit/src/{ndsrecomp,recomp-ui}
else()
    set(UI_ROOT "${RECOMP_ROOT}/recomp-ui")
endif()
set(NDS_RECOMP_UI_ROOT "${UI_ROOT}" CACHE PATH "" FORCE)

# nds_runner's build defines an executable. Intercept only that target, retaining
# its source list, options and dependency graph for Android's JNI library.
macro(add_executable name)
    if("${name}" STREQUAL "nds_runner")
        add_library(${name} SHARED ${ARGN})
    else()
        _add_executable(${name} ${ARGN})
    endif()
endmacro()
add_subdirectory("${RUNNER_ROOT}" "${CMAKE_CURRENT_BINARY_DIR}/runner" EXCLUDE_FROM_ALL)
# The runtime is explicitly FreeBIOS-only. Remove retail BIOS-derived objects
# from the archive, and satisfy the unreachable retail branch with empty tables.
get_target_property(bank_sources nds_banks SOURCES)
foreach(cpu arm7 arm9)
    list(REMOVE_ITEM bank_sources "${NDS_GENERATED_DIR}/${cpu}_bios.c" "${NDS_GENERATED_DIR}/${cpu}_bios_dispatch.c")
endforeach()
set_property(TARGET nds_banks PROPERTY SOURCES "${bank_sources}")
target_sources(nds_banks PRIVATE "${CMAKE_CURRENT_LIST_DIR}/retail_bios_stubs.c")
# Android has no bundled live-overlay compiler. Use a local platform shim so
# builds never depend on unrelated uncommitted edits in the framework checkout.
get_target_property(runner_sources nds_runner SOURCES)
list(FIND runner_sources "src/live_overlay_platform.cpp" platform_index)
if(platform_index EQUAL -1)
    message(FATAL_ERROR "Upstream live-overlay platform source changed; update the Android shim")
endif()
list(REMOVE_AT runner_sources ${platform_index})
set_property(TARGET nds_runner PROPERTY SOURCES "${runner_sources}")
target_sources(nds_runner PRIVATE "${CMAKE_CURRENT_LIST_DIR}/live_overlay_platform_android.cpp")
set_property(SOURCE "${RUNNER_ROOT}/src/main.cpp" TARGET_DIRECTORY nds_runner APPEND PROPERTY
    COMPILE_DEFINITIONS main=nds_android_main debug_pump_start=nds_android_debug_pump_start debug_pump_stop=nds_android_debug_pump_stop)
set_property(SOURCE "${RUNNER_ROOT}/src/frontend.cpp" TARGET_DIRECTORY nds_runner APPEND PROPERTY
    COMPILE_DEFINITIONS nds_run_interactive_frontend=nds_desktop_interactive_frontend)
target_sources(nds_runner PRIVATE android_frontend.cpp)
# On Windows CMake may invoke clang++ via an 8.3 alias, causing the driver to
# miss its C++ mode and omit libc++; link it explicitly for reproducibility.
target_link_libraries(nds_runner PRIVATE c++_shared log android)
